that's a good idea. Keep in mind,
Temporary items disappear when closing file.
Function Dialog_Edit_Autotext_mod6a
or we can create the backup in a new folder. Then you can delete when you like.
Temporary items disappear when closing file.
Function Dialog_Edit_Autotext_mod6a
str- sItems sdItems
sub.DisableEnableAutoText(1 "" sItems sdItems)
str dd=
;BEGIN DIALOG
;0 "" 0x90C80AC8 0x0 0 0 334 214 "Edit Existing AutoText"
;3 Edit 0x54030080 0x200 9 8 120 14 ""
;4 ListBox 0x54230101 0x200 9 22 120 157 ""
;5 Edit 0x54030080 0x200 145 8 174 14 ""
;6 ListBox 0x54330101 0x200 145 22 174 157 ""
;7 Button 0x54032000 0x0 188 192 89 14 "Sort AutoText Code in QM" "Sort Autotext function in qm"
;1 Button 0x54030001 0x4 116 216 48 14 "OK"
;2 Button 0x54030000 0x4 168 216 48 14 "Cancel"
;END DIALOG
;DIALOG EDITOR: "" 0x2040A00 "*" "" "" ""
str controls = "3 4 5 6"
str e3 lb4 e5 lb6
lb4=sItems
if(!ShowDialog(dd &sub.DlgProc &controls)) ret
#sub DlgProc
function# hDlg message wParam lParam
str- itemslb2 itemslb2a itemslb2b
int- lb6lc
str- sItems
int i
str- sdItems
sel message
,case WM_INITDIALOG
,SetWindowSubclass((id(3 hDlg)) &sub.EditSubclassProc 3 0)
,SetWindowSubclass((id(5 hDlg)) &sub.EditSubclassProc 5 0)
,SetWindowSubclass(id(6 hDlg) &sub.ListBoxSubclassProc 6 0)
,case WM_DESTROY
,case WM_COMMAND goto messages2
,case WM_TIMER
,sel wParam
,,case 1
,,KillTimer hDlg wParam
,,int hlb=id(4 hDlg)
,,SendMessage hlb LB_RESETCONTENT 0 0
,,str s3 sEdit3.getwintext(id(3 hDlg))
,,foreach s3 sItems
,,,if(sEdit3.len and find(s3 sEdit3 0 1)<0) continue
,,,LB_Add hlb s3
,,int count=LB_GetCount(hlb)
,,if count=1;; auto select list item if only 1 item is left when searching
,,,SendMessage hDlg WM_COMMAND LBN_SELCHANGE<<16|GetDlgCtrlID(hlb) hlb
,,case 2
,,KillTimer hDlg wParam
,,int hlb2a=id(6 hDlg)
,,SendMessage hlb2a LB_RESETCONTENT 0 0
,,str s5 sEdit5.getwintext(id(5 hDlg))
,,foreach s5 itemslb2
,,,if(sEdit5.len and find(s5 sEdit5 0 1)<0) continue
,,,LB_Add hlb2a s5
,,int count2=LB_GetCount(hlb2a)
,,if count2=1
,,,LB_SelectItem(hlb2a 0)
ret
;messages2
int h=GetQmCodeEditor
int hlb2=id(6 hDlg) ;;list box 2
sel wParam
,case IDOK
,sub.DisableEnableAutoText(2 sdItems)
,case IDCANCEL
,sub.DisableEnableAutoText(3 sdItems)
,case EN_CHANGE<<16|3
,SetTimer hDlg 1 100 0
,case EN_CHANGE<<16|5
,SetTimer hDlg 2 100 0
,case LBN_SELCHANGE<<16|4
,str lb1si
,_i=LB_SelectedItem(lParam lb1si)
,if(_i=-1)
,,LB_SelectItem(lParam 0)
,,_i=LB_SelectedItem(lParam lb1si)
,sub.IsSorted(lb1si)
,str lb2ii
,itemslb2=sub.gotoitemedit(lb1si)
,itemslb2b=itemslb2
,SendMessage(hlb2 LB_RESETCONTENT 0 0)
,;itemslb2.findreplace(":sub." " ")
,;itemslb2.findreplace(";;" " ")
,;itemslb2.findreplace(":" " ")
,if(itemslb2.len)
,,itemslb2.replacerx(":sub.Sub\d+\s;;" " ") ;;Replace extra characters
,,itemslb2a=itemslb2
,,foreach lb2ii itemslb2
,,,LB_Add(hlb2 lb2ii)
,,lb6lc=LB_GetCount(hlb2)
,case LBN_DBLCLK<<16|4
,_i=LB_SelectedItem(lParam _s)
,mac+ _s
,case LBN_DBLCLK<<16|6
,str lb2t
,_i=LB_SelectedItem(lParam lb2t)
,if(_i=-1)
,,LB_SelectItem(lParam 0)
,,LB_SelectedItem(lParam lb2t)
,ARRAY(str) b=itemslb2a
,for i 0 b.len
,,if(StrCompare(b[i] lb2t)=0)
,,,_i=i
,,,break
,LB_SelectedItem(id(4 hDlg) _s)
,mac+ _s
,act h
,SendMessage(h SCI.SCI_GOTOLINE _i+1 0)
,str lineText.getl(itemslb2b _i)
,int ii=find(lineText "sub." 0 1)
,if ii!=-1
,,int cp=SendMessage(h SCI.SCI_GETCURRENTPOS 0 0)
,,cp+ii+4
,,SendMessage(h SCI.SCI_GOTOPOS cp 0)
,sub.FlashCodeLine(_i+1 h)
,clo hDlg
,case 7 ;;Sort autotext code in qm not dialog
,LB_SelectedItem(id(4 hDlg) _s)
,int retVal=sub.IsSorted(_s hDlg 1)
,if(retVal=0)
,,mac "sub.ShowMessage" "" F"Sorting of Autotext code in {_s} is not rquired at this time" "Sort Message"
,else
,,mac "sub.ShowMessage" "" F"Autotext code in {_s} has been sorted" "Sort Message"
ret 1
#sub gotoitemedit
function~ ~name
str pattern="(?m)^(.+\s\:.+)"
_s.getmacro(name 0)
str d
int i
ARRAY(str) a
findrx(_s pattern 0 4 a)
for i 0 a.len
,d.formata("%s[]" a[0 i].trim)
ret d
#sub Callback_q_sort
function# param str&a str&b
str s.gett(a -1 ":") ;str ss.gett(b -1 ":")
if(StrCompare(s ss)=0)
,ret StrCompare(a+findcr(a ';')+1 b+findcr(b ';')+1 1)
else
,ret StrCompare(a b 1)
#sub FlashCodeLine
function line hce
if(!hce) hce=GetQmCodeEditor
act hce
int indicator=19
SendMessage(hce SCI.SCI_SETINDICATORCURRENT indicator 0)
SendMessage(hce SCI.SCI_INDICSETALPHA indicator 100)
SendMessage(hce SCI.SCI_INDICSETFORE indicator 0x00FF00)
SendMessage(hce SCI.SCI_INDICSETSTYLE indicator SCI.INDIC_STRAIGHTBOX)
SendMessage(hce SCI.SCI_INDICSETUNDER indicator TRUE)
int lsp=SendMessage(hce SCI.SCI_POSITIONFROMLINE line 0)
int lep=SendMessage(hce SCI.SCI_GETLINEENDPOSITION line 0)
rep 4
,SendMessage(hce SCI.SCI_INDICATORFILLRANGE lsp lep-lsp)
,0.25
,SendMessage(hce SCI.SCI_INDICATORCLEARRANGE lsp lep-lsp)
,0.25
SendMessage(hce SCI.SCI_SETINDICATORCURRENT 0 0)
#sub EditSubclassProc
function# hwnd message wParam lParam uIdSubclass dwRefData
int Phwnd= GetParent(hwnd)
;OutWinMsg message wParam lParam
sel message
,case WM_GETDLGCODE
,sel(wParam) case VK_RETURN ret DLGC_WANTALLKEYS ;;send WM_KEYDOWN instead of closing the dialog
,case WM_CHAR
,sel(wParam) case VK_RETURN ret 0
,case WM_KEYDOWN
,sel wParam ;;virtual key code
,,case VK_RETURN
,,;on enter in the edit box select the item in the list box
,,sel uIdSubclass
,,,case 3
,,,SendMessage Phwnd WM_COMMAND LBN_SELCHANGE<<16|GetDlgCtrlID(id(4 Phwnd)) id(4 Phwnd)
,,,case 5
,,,SendMessage Phwnd WM_COMMAND LBN_DBLCLK<<16|GetDlgCtrlID(id(6 Phwnd)) id(6 Phwnd)
,,ret
,,case [VK_DOWN,VK_UP,VK_PRIOR,VK_NEXT]
,,;relay these keys to the listbox and not to the edit box
,,sel uIdSubclass
,,,case 3
,,,SendMessage id(4 Phwnd) message wParam lParam
,,,case 5
,,,SendMessage id(6 Phwnd) message wParam lParam
,,ret
int R=DefSubclassProc(hwnd message wParam lParam)
sel message
,case WM_NCDESTROY
,RemoveWindowSubclass(hwnd &sub.EditSubclassProc uIdSubclass)
ret R
#sub ListBoxSubclassProc
function# hwnd message wParam lParam uIdSubclass dwRefData
sel message
,case WM_GETDLGCODE
,sel(wParam) case VK_RETURN ret DLGC_WANTALLKEYS ;;send WM_KEYDOWN instead of closing the dialog
,case WM_KEYDOWN
,sel(wParam) case VK_RETURN SendMessage GetParent(hwnd) WM_COMMAND LBN_DBLCLK<<16|uIdSubclass hwnd; ret
int R=DefSubclassProc(hwnd message wParam lParam)
sel message
,case WM_NCDESTROY
,RemoveWindowSubclass(hwnd &sub.ListBoxSubclassProc uIdSubclass)
ret R
#sub DisableEnableAutoText
function mode [str'dati] [str&atItems] [str&atditems]
QMITEM q; int i
ARRAY(str) atn atd
rep
,i=qmitem(-i 1|16 &q 1)
,if(i=0) break
,if q.itype=4
,,atn[]=q.name
,,sel mode
,,,case 1 ;;disable
,,,if(dis(q.name)) atd[]=q.name
,,,else dis+ q.name
,,,case else ;;enable
,,,int fdat=findw(dati q.name 0 "[]")
,,,if fdat = -1
,,,,dis- q.name
if(mode <>1) ret
atn.sort(8)
atItems=atn
atditems=atd
#sub getAutotextItem
function~ ~name &sep
str pattern="(?m)^(.+\s\:.+)"
_s.getmacro(name 0);
ARRAY(CHARRANGE) a; int i
findrx(_s pattern 0 4 a)
str items t
for i 0 a.len
,int offset(a[0 i].cpMin) length(a[0 i].cpMax-a[0 i].cpMin)
,t.get(_s offset length)
,items.formata("%s[]" t.trim)
,sep=offset+length
ret items
#sub IsSorted
function ~name [hwnd] [mode]
str s.getmacro(name 0)
str ss atCode=sub.gotoitemedit(name)
ARRAY(str) a b c
a=atCode; b=atCode; c=s
a.sort(2 sub.Callback_q_sort)
int i sval
for(i 0 b.len)
,if(StrCompare(a[i] b[i]) <>0)
,,sval=1
,,break
if(sval =0)
,ret
;; create backup of autotetx function as Temp Item
int ni=newitem(F"Temp_{name}_" s "Autotext" "" "" 128)
str tempName.getmacro(ni 1)
out F"<> a backup of {name} has been created as <open>{tempName}</open> in the Temp folder"
i=0
for int'j 1 c.len
,if(i<a.len)
,,c[j]=a[i]
,i+1
ss=c
ss.rtrim
ss.setmacro(name)
if(mode=1)
,_i=LB_SelectedItem(id(4 hwnd))
,LB_SelectItem(id(4 hwnd) _i-1)
,0.5
,LB_SelectItem(id(4 hwnd) _i)
ret 1
#sub ShowMessage
function ~text ~caption
mes text captionor we can create the backup in a new folder. Then you can delete when you like.